Inhalte
Index 🔎︎

# Dienst SFDialogs.Dialog

Der Dienst Dialog trägt zur Verwaltung von Dialogen bei, die mit dem Dialogeditor Basic erstellt wurden. Jede Instanz der aktuellen Klasse stellt einen einzelnen Dialog dar, der dem Benutzer angezeigt wird.

Der Dialog kann im modalen oder im nicht-modalen Modus angezeigt werden.

Im modalen Modus wird das Feld angezeigt und die Ausführung des Makroprozesses ausgesetzt, bis eine der Schaltflächen „OK“ oder „Abbrechen“ gedrückt wird. In der Zwischenzeit können auf der Box ausgeführte Benutzeraktionen bestimmte Aktionen auslösen.

Im nicht-modalen Modus „schwebt“ der Dialog auf dem Desktop des Benutzers und die Ausführung des Makroprozesses wird normal fortgesetzt. Der nicht-modale Dialog wird geschlossen, wenn er mit der Methode Terminate() beendet wird oder wenn die LibreOfficeDev-Sitzung endet. Die Schaltfläche zum Schließen des Fensters ist in nicht-modalen Dialogen inaktiv.

Der Dialog verschwindet nach seiner expliziten Beendigung aus dem Speicher.

Der Dienst SFDialogs.Dialog ist eng mit dem Dienst SFDialogs.DialogControl verwandt.

## Dienstaufruf und Nutzung

Vor der Verwendung des Dienstes Dialog muss die Bibliothek ScriptForge geladen oder importiert werden:

• Grundlegende Makros erfordern das Laden der Bibliothek ScriptForge mit der folgenden Anweisung:
GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
• Python-Skripte erfordern einen Import aus dem Modul scriptforge:
from scriptforge import CreateScriptService

Der Dienst Dialog wird über die Methode CreateScriptService aufgerufen. Es erfordert drei Positionsargumente, um den zu aktivierenden Dialog anzugeben:

Container: "GlobalScope" für vorinstallierte Bibliotheken oder ein Fenstername wie vom Dienst ScriptForge.UI definiert. Der Standardwert leere Zeichenfolge "" steht für das aktuelle Dokument.

Library: Der Name einer im Container enthaltenen Bibliothek, bei der die Groß-/Kleinschreibung beachtet wird. Der Standardwert ist "Standard".

DialogName: Eine Zeichenfolge mit Berücksichtigung der Groß-/Kleinschreibung, die den Dialog bezeichnet.

Die folgenden Beispiele in Basic und Python zeigen den Dialog dlgConsole, der zur gemeinsam genutzten Bibliothek ScriptForge gehört:

          Dim oDlg As Object, lButton As Long
          Dim Container As String, Library As String, DialogName As String
          Set oDlg = CreateScriptService("SFDialogs.Dialog", "GlobalScope", "ScriptForge", "dlgConsole")
          ' … Steuerungsinitialisierung startet hier …
          lButton = oDlg.Execute()
          ' Standardmodus = Modal
          If lButton = oDlg.OKBUTTON Then
          ' … Prozesskontrollen und erledigen, was hier nötig ist
          End If
          oDlg.Terminate()

Oder mit Python:

        dlg = CreateScriptService('SFDialogs.Dialog', 'GlobalScope', 'ScriptForge', 'dlgConsole')
        # … Steuerungsinitialisierung startet hier …
        rc = dlg.Execute()
        # Standardmodus ist Modal
        if rc == dlg.OKBUTTON:
            # … Prozesskontrollen und erledigen, was hier nötig ist
        dlg.Terminate()

Verwenden Sie die Zeichenfolge "GlobalScope" als Argument container, wenn der Dialog entweder in Meine Makros und Dialoge oder in Anwendungsmakros und -dialoge gespeichert ist.

## Abrufen der Instanz "Dialog", die ein Dialogereignis ausgelöst hat

Eine Instanz des Dienstes Dialog kann über den Dienst SFDialogs.DialogEvent abgerufen werden, sofern der Dialog mit dem Dienst Dialog initiiert wurde. Im Beispiel unten enthält oDlg die Instanz Dialog, die das Dialogereignis ausgelöst hat.

        Sub aDialogEventHander(ByRef poEvent As Object)
            Dim oDlg As Object
            Set oDlg = CreateScriptService("SFDialogs.DialogEvent", poEvent)
            ' ...
        End Sub

Oder mit Python:

        def control_event_handler(event: uno):
            dlg = CreateScriptService("SFDialogs.DialogEvent", event)
            # ...

Beachten Sie, dass in den vorherigen Beispielen das Präfix "SFDialogs." weggelassen werden kann, wenn es angebracht erscheint.

## Behandlung von Ausnahmen in Ereignishandlern

Beim Erstellen einer Ereignisbehandlungsroutine für Dialogereignisse empfiehlt es sich, Fehler innerhalb der Subroutine selbst zu behandeln. Angenommen, der unten stehende Ereignishandler wird aufgerufen, wenn die Maustaste im Dialogfenster gedrückt wird.

        Sub OnMouseButtonPressed(ByRef oEvent As Object)
        On Local Error GoTo Catch
            Dim oDialog As Object
            oDialog = CreateScriptService("DialogEvent", oEvent)
            ' Das Ereignis verarbeiten
            Exit Sub
        Catch:
            MsgBox SF_Exception.Description
            SF_Exception.Clear
        End Sub

Rufen Sie SF_Exception.Clear auf, wenn Sie nicht möchten, dass der Fehler nach Beendigung der Dialogausführung weitergegeben wird.

Verwenden Sie in Python native Blöcke try/except für die Ausnahmebehandlung, wie unten gezeigt:

        def on_mouse_button_pressed(event=None):
            try:
                dlg = CreateScriptService("DialogEvent", event)
                # Verarbeite das Ereignis
            except Exception as e:
                # Das Objekt "bas" ist eine Instanz des Dienstes Basic
                bas.MsgBox(str(e))

## Eigenschaften

Name | Schreibgeschützt | Typ | Beschreibung
--- | --- | --- | ---
OKBUTTON | Ja | Integer | Wert = 1. Die Schaltfläche "OK" wurde gedrückt.
CANCELBUTTON | Ja | Integer | Wert = 0. Die Schaltfläche "Abbrechen" wurde gedrückt.
Caption | Nein | String | Legt den Titel des Dialogs fest.
Height | Nein | Long | Legt die Höhe des Dialogs fest.
Modal | Ja | Boolean | Legt fest, ob der Dialog derzeit im modalen Modus ausgeführt wird.
Name | Ja | String | Der Name des Dialogs
Page | Nein | Integer | Der Dialog kann mehrere Seiten haben, die vom Benutzer Schritt für Schritt durchlaufen werden können. Die Eigenschaft "Page" des Objekts "Dialog" definiert, welche Seite des Dialogs aktiv ist.
Visible | Nein | Boolean | Legt fest, ob der Dialog auf dem Desktop sichtbar ist. Standardmäßig ist er nicht sichtbar, bis die Methode "Execute()" ausgeführt wird und danach sichtbar ist.
XDialogModel | Ja | UNO object | Das UNO-Objekt, welches das Dialogmodell darstellt. Siehe XControlModel und UnoControlDialogModel in der Programmierschnittstelle (API).
XDialogView | Ja | UNO object | Das UNO-Objekt, das die Dialogansicht darstellt. Siehe XControl und UnoControlDialog in der Dokumentation der Programmierschnittstelle (API) für detaillierte Informationen.
Width | Nein | Long | Legt die Breite des Dialogs fest.

## Ereigniseigenschaften

Gibt eine URI-Zeichenfolge mit dem Verweis auf das durch das Ereignis ausgelöste Skript zurück. Lesen Sie die Spezifikation unter scripting framework URI specification nach.

Name | Schreibgeschützt | Basic-IDE-Beschreibung
--- | --- | ---
OnFocusGained | Ja | Beim Erhalten des Fokus
OnFocusLost | Ja | Beim Verlust des Fokus
OnKeyPressed | Ja | Beim Tastendruck
OnKeyReleased | Ja | Beim Taste loslassen
OnMouseDragged | Ja | Bei Mausbewegung während Tastedruck
OnMouseEntered | Ja | Maus hinein
OnMouseExited | Ja | Maus heraus
OnMouseMoved | Ja | Mausbewegung
OnMousePressed | Ja | Mausklick
OnMouseReleased | Ja | Maustaste lösen

List of Methods in the Dialog Service
Activate Center Controls | EndExecute Execute GetTextsFromL10N | Resize SetPageManager Terminate

## Activate

Setzt den Fokus auf die aktuelle Instanz von Dialog. Gib True zurück, wenn die Fokussierung erfolgreich war.

Diese Methode wird von einem Dialog- oder Steuerereignis aufgerufen oder wenn ein Dialog im nicht-modalen Modus angezeigt wird.

### Syntax:

svc.Activate(): bool

### Beispiel:

          Dim oDlg As Object
          Set oDlg = CreateScriptService(,, "myDialog")
          oDlg.Execute()
          ' ...
          oDlg.Activate()

Python- und LibreOfficeDev Basic-Beispiele setzen beide voraus, dass der Dialog in der Bibliothek Standard des aktuellen Dokuments gespeichert ist.

         dlg = CreateScriptService(,,'myDialog')
         dlg.Execute()
         # ...
         dlg.Activate()

## Center

Zentriert den aktuellen Dialog in der Mitte eines übergeordneten Fensters. Ohne Argumente zentriert die Methode den Dialog in der Mitte des aktuellen Fensters.

Gibt bei Erfolg True zurück.

### Syntax:

svc.Center(opt Parent: obj): bool

### Parameter:

Parent: Ein optionales Objekt …

- ein Dialog "ScriptForge"

- ein Dokument (Calc, Base, …) "ScriptForge"

### Beispiel:

##### In Basic

         Sub TriggerEvent(oEvent As Object)
             Dim oDialog1 As Object, oDialog2 As Object, lExec As Long
             Set oDialog1 = CreateScriptService("DialogEvent", oEvent) ' Der Dialog, der das Ereignis verursacht hat
             Set oDialog2 = CreateScriptService("Dialog", …) ' Öffnet einen zweiten Dialog
             oDialog2.Center(oDialog1)
             lExec = oDialog2.Execute()
             Select Case lExec
                 ...
         End Sub

##### In Python

         def triggerEvent(event: uno):
           dlg1 = CreateScriptService('DialogEvent.Dialog', event) # Der Dialog, der das Ereignis verursacht hat
           dlg2 = CreateScriptService('Dialog', …)  # Öffnet einen zweiten Dialog
           dlg2.Center(dlg1)
           rc = dlg2.Execute()
           if rc is False:
             # ...

## Controls

Rückgabe:

- die Liste der im Dialog enthaltenen Steuerelemente

- eine Klasseninstanz von DialogControl basierend auf ihrem Namen

### Syntax:

svc.Controls(): str[0..*]

svc.Controls(controlname: str): svc

### Parameter:

ControlName: Ein gültiger Steuerelementname als Zeichenfolge mit Beachtung der Groß-/Kleinschreibung. Wenn nicht vorhanden, wird die Liste der Steuerelementnamen als nullbasierte Matrix zurückgegeben.

### Beispiel:

          Dim myDialog As Object, myList As Variant, myControl As Object
          Set myDialog = CreateScriptService("SFDialogs.Dialog", , "Standard", "Dialog1")
          myList = myDialog.Controls()
          Set myControl = myDialog.Controls("myTextBox")

         dlg = CreateScriptService('SFDialogs.Dialog','', 'Standard', 'Dialog1')
         ctrls = dlg.Controls()
         ctrl = dlg.Controls('myTextBox')

## EndExecute

Beendet die Anzeige eines modalen Dialogs und gibt das Argument als Rückgabewert für die aktuell laufende Aktion Execute() zurück.

EndExecute() ist normalerweise in der Verarbeitung eines Makros enthalten, das durch ein Dialog- oder Steuerereignis ausgelöst wird.

### Syntax:

svc.EndExecute(returnvalue: int)

### Parameter:

returnvalue: Der Wert, der an die laufende Methode Execute() übergeben wird.

### Beispiel:

Verwendung von LibreOfficeDev-Basic:

          Sub OnEvent(poEvent As com.sun.star.lang.EventObject)
              Dim oDlg As Object
              Set oDlg = CreateScriptService("SFDialogs.DialogEvent", poEvent)
              oDlg.EndExecute(ReturnValue := 25)
          End Sub

Verwendung von Python:

         from com.sun.star.lang import EventObject
         def on_event(event: EventObject):
             dlg = CreateScriptService("SFDialogs.DialogEvent", event)
             dlg.EndExecute(25)

Obige Erwähnungen von com.sun.star.lang.EventObject sind optional. Solche Anmerkungen helfen bei der Identifizierung der LibreOfficeDev-Programmierschnittstelle (API).

## Execute

Zeigt den Dialog an und wartet, wenn es modal ist, auf seine Beendigung durch den Benutzer. Der zurückgegebene Wert ist:

- 0: Schaltfläche Abbrechen gedrückt

- 1: Schaltfläche OK gedrückt

- Andernfalls wurde der Dialog mit einer Anweisung EndExecute() beendet, die von einem Dialog- oder Steuerereignis ausgegeben wurde

Bei nicht-modalen Dialogen gibt die Methode immer 0 zurück und die Ausführung des Makros wird fortgesetzt.

### Syntax:

svc.Execute(modal: bool = True): int

### Parameter:

modal: False bei nicht-modalem Dialog. Standard = True.

### Beispiel:

In diesem einfachen Beispiel wird der Dialog myDialog in der Bibliothek Standard des aktuellen Dokuments gespeichert.

          Dim oDlg As Object, lReturn As Long
          Set oDlg = CreateScriptService("SFDialogs.Dialog", , , "myDialog")
          lReturn = oDlg.Execute(Modal := False)
          Select Case lReturn
              ' ...
          End Select

Dieser Python-Code zeigt den modalen Dialog DlgConvert aus der gemeinsamen Basisbibliothek Euro an.

         dlg = CreateScriptService("SFDialogs.Dialog", 'GlobalScope', 'Euro', "DlgConvert")
         rc = dlg.Execute()
         if rc == dlg.CANCELBUTTON:
             # ...

## GetTextsFromL10N

Ersetzt alle festen Textzeichenfolgen in einem Dialog durch ihre übersetzten Versionen basierend auf einer Dienstinstanz L10N. Diese Methode übersetzt die folgenden Zeichenfolgen:

- Der Titel des Dialogs.

- Die Beschriftung der folgenden Steuerelementtypen: Schaltfläche, Markierfeld, Geschützte Linie, Beschriftungsfeld, Gruppenfeld und Optionsfeld.

- Statische Zeichenfolgen in Listenfeldern und Kombinationsfeldern.

- Der Hilfetext, der angezeigt wird, wenn die Maus über das Steuerelement bewegt wird.

Die Methode gibt bei Erfolg True zurück.

Verwenden Sie zum Erstellen einer Liste übersetzbarer Zeichenfolgen in einem Dialog die Methode AddTextsFromDialog des Dienstes "L10N".

### Syntax:

svc.GetTextsFromL10N(l10n: svc): bool

### Parameter:

l10n: Eine Dienstinstanz L10N, von der übersetzte Zeichenfolgen abgerufen werden.

### Beispiel:

Das folgende Beispiel lädt übersetzte Zeichenfolgen und wendet sie auf den Dialog "MyDialog" an.

##### In Basic

         oDlg = CreateScriptService("Dialog", "GlobalScope", "Standard", "MyDialog")
         myPO = CreateScriptService("L10N", "/home/user/po_files/")
         oDlg.GetTextsFromL10N(myPO)
         oDlg.Execute()

##### In Python

         dlg = CreateScriptService("Dialog", "GlobalScope", "Standard", "MyDialog")
         myPO = CreateScriptService("L10N", "/home/user/po_files/")
         dlg.GetTextsFromL10N(myPO)
         dlg.Execute()

Lesen Sie die Hilfeseite zum Dienst L10N, um mehr darüber zu erfahren, wie PO- und POT-Dateien gehandhabt werden.

## Resize

Verschiebt die obere linke Ecke eines Dialogs auf neue Koordinaten und/oder ändert seine Abmessungen. Alle Abstände sind in 1/100 mm angegeben. Ohne Argumente setzt die Methode die anfänglichen Dimensionen zurück. Gibt True zurück, wenn die Größenänderung erfolgreich war.

### Syntax:

svc.Resize(opt Left: num, opt Top: num, opt Width: num, opt Height: num): bool

### Parameter:

Left: der horizontale Abstand von der oberen linken Ecke

Top: Der vertikale Abstand von der oberen linken Ecke

Width: die Breite des Rechtecks, das den Dialog enthält

Height: die Höhe des Rechtecks, das den Dialog enthält

Negative oder fehlende Argumente bleiben unverändert

### Beispiel:

##### In Basic

         oDialog.Resize(1000, 2000, Height := 6000) ' Die Breite wird nicht verändert

##### In Python

Mit Python:

         oDialog.Resize(1000, 2000, Height = 6000)  # Die Breite wird nicht verändert

## SetPageManager

Definiert, welche Steuerelemente in einem Dialog für das Wechseln von Seiten verantwortlich sind, wodurch die Verwaltung der Eigenschaft Page eines Dialogs und seiner Steuerelemente vereinfacht wird.

Dialoge können mehrere Seiten haben und die aktuell sichtbare Seite wird durch die Dialogeigenschaft Page definiert. Wenn die Eigenschaft Page unverändert gelassen wird, ist die standardmäßig sichtbare Seite gleich 0 (Null), was bedeutet, dass keine bestimmte Seite definiert ist und alle sichtbaren Steuerelemente angezeigt werden, unabhängig von dem Wert, der in ihrer eigenen Eigenschaft Page gesetzt ist.

Wenn die Eigenschaft Page eines Dialogs auf einen anderen Wert als 1, 2, 3 und so weiter geändert wird, dann werden nur die Steuerelemente angezeigt, deren Eigenschaft Page mit der aktuellen Dialogseite übereinstimmen.

Durch die Verwendung der Methode SetPageManager ist es möglich, vier Arten von Seitenmanagern zu definieren:

- Listenfeld oder Kombinationsfeld: hier entspricht jeder Eintrag in dem Listen- oder Kombinationsfeld einer Seite. Das erste Element bezieht sich auf Seite 1, das zweite Element bezieht sich auf Seite 2 und so weiter.

- Gruppe von Optionsfeldern: definiert eine Gruppe von Optionsfeldern, die steuern, welche Seite sichtbar ist.

- Sequence of buttons: defines a set of buttons, each of which corresponding to a dialog page. This can be used to emulate a tabbed interface by placing buttons side by side in the dialog.

- Schaltflächen Vorherige/Nächste: definiert, welche Schaltflächen im Dialog verwendet werden, um zur vorherigen/nächsten Seite im Dialog zu navigieren.

Es ist möglich, mehr als einen Seitenverwaltungsmechanismus gleichzeitig zu verwenden.

Diese Methode sollte nur einmal aufgerufen werden, bevor die Methode Execute aufgerufen wird. Nachfolgende Aufrufe werden ignoriert.

Bei Erfolg gibt diese Methode True zurück.

### Syntax:

svc.SetPageManager(pilotcontrols: str = "", tabcontrols: str = "", wizardcontrols: str = "", opt lastpage: int): bool

### Parameter:

pilotcontrols: eine durch Kommas getrennte Liste von Steuerelementennamen ListBox, ComboBox oder RadioButton, die als Seitenmanager verwendet werden. Geben Sie für Steuerelemente "RadioButton" den Namen des ersten zu verwendenden Steuerelements in der Gruppe an.

Tabcontrols: eine durch Kommas getrennte Liste von Schaltflächennamen, die als Seitenmanager verwendet werden. Die Reihenfolge, in der sie in diesem Argument angegeben werden, entspricht der Seitenzahl, der sie zugeordnet sind.

wizardcontrols: eine durch Kommas getrennte Liste mit den Namen von zwei Schaltflächen, die als Schaltflächen Zurück/Weiter verwendet werden.

lastpage: die Nummer der letzten verfügbaren Seite. Es wird empfohlen, diesen Wert anzugeben, wenn Sie den Manager für vorherige/nächste Seite verwenden.

### Beispiel:

Stellen Sie sich einen Dialog mit drei Seiten vor. Der Dialog hat ein Steuerelement ListBox namens "aPageList", das verwendet wird, um die sichtbare Seite zu steuern. Zusätzlich gibt es zwei Schaltflächen mit den Namen "btnPrevious" und "btnNext", die als Schaltflächen Zurück/Weiter im Dialog verwendet werden.

##### In Basic

        oDialog.SetPageManager(PilotControls := "aPageList", _
                               WizardControls := "btnPrevious,btnNext", _
                               LastPage := 3)
        oDialog.Execute()

##### In Python

        dlg.SetPageManager(pilotcontrols="aPageList",
                           wizardcontrols="btnPrevious,btnNext",
                           lastpage=3)
        dlg.Execute()

## Terminate

Beendet den Dienst Dialog für die aktuelle Instanz. Gibt True zurück, wenn die Beendigung erfolgreich war.

### Syntax:

svc.Terminate(): bool

### Beispiel:

Die folgenden Basic- und Python-Beispiele öffnen die nicht-modalen Dialoge DlgConsole und dlgTrace. Sie werden jeweils in gemeinsam genutzten Bibliotheken von ScriptForge und Access2Base gespeichert. Schaltflächen zum Schließen von Dialogen sind deaktiviert und eine explizite Beendigung wird am Ende eines laufenden Prozesses durchgeführt.

In diesem Beispiel ersetzt eine Schaltfläche in DlgConsole das gesperrte Schließen des Fensters:

##### In Basic

         oDlg = CreateScriptService("SFDialogs.Dialog","GlobalScope","ScriptForge","DlgConsole")
         oDlg.Execute(modal:=False)
         Wait 5000
         oDlg.Terminate()

Mit Python:

##### In Python

         from time import sleep
         dlg = CreateScriptService('SFDialogs.Dialog',"GlobalScope",'Access2Base',"dlgTrace")
         dlg.Execute(modal=False)
         sleep 5
         dlg.Terminate()

Alle ScriptForge Basic-Routinen oder Bezeichner, denen ein Unterstrich "_" vorangestellt ist, sind für den internen Gebrauch reserviert. Sie sind nicht für die Verwendung in Basic-Makros oder Python-Skripten vorgesehen.

Verwandte Themen

Dienst SFDialogs.DialogControl

Dienst ScriptForge.UI