Tartalom
Index 🔎︎

# Információs függvények

A kategória az információs függvényeket tartalmazza.

Ennek a parancsnak az eléréséhez...

Válassza a Beszúrás - Függvény - Kategória: Információ lehetőséget.

Az alábbi táblázatban szereplő adatokra épülnek a függvényleírásoknál használt példák:

| C | D
2 | x value | y value
3 | -5 | -3
4 | -2 | 0
5 | -1 | 1
6 | 0 | 3
7 | 2 | 4
8 | 4 | 6
9 | 6 | 8

## CELLA

Információkat ad vissza egy cella címéről, formázásáról vagy tartalmáról.

#### Szintaxis

CELLA("információtípus" [; hivatkozás])

Az információtípus egy karakterlánc, amely meghatározza az információ típusát. A karakterlánc nyelve mindig angol. A kis-, illetve nagybetűk egyaránt használhatók.

Információtípus | Jelentés
--- | ---
COL | A hivatkozott oszlop számát adja vissza. Az =CELLA("OSZLOP";D2) függvény a 4 értéket adja vissza.
ROW | A hivatkozott sor számát adja vissza. A =CELLA("ROW";D2) függvény a 2 értéket adja vissza.
SHEET | A hivatkozott munkalap számát adja vissza. A =CELLA("lap";Munkalap3.D2) függvény a 3 értéket adja vissza.
ADDRESS | A hivatkozott cella abszolút címét adja vissza. A =CELLA("CÍM";D2) függvény a $D$2 értéket adja vissza. A =CELLA("CÍM";Munkalap3.D2) függvény a $Munkalap3.$D$2 értéket adja vissza. A =CELLA("CÍM";'X:\dr\teszt.ods'#$Munkalap1.D2) a 'file:///X:/dr/teszt.ods'#$Munkalap1.$D$2 értéket adja vissza.
FILENAME | A hivatkozott cella munkalap- és fájlnevét adja vissza. A =CELLA("FILENÉV";D2) a ''file:///X:/dr/sajat.ods'#$Munkalap1 értéket adja vissza, ha a képlet az aktuális dokumentumban (X:\dr\sajat.ods), a Munkalap1 munkalapon található. A =CELLA("FILENÉV";'X:\dr\teszt.ods'#$Munkalap1.D2) a 'file:///X:/dr/teszt.ods'#$Munkalap1 értéket adja vissza.
COORD | A teljes cella címet Lotus(™)-jelölésben adja vissza. A =CELLA("KOORD";D2) függvény a $A:$D$2 értéket adja vissza. A =CELLA("KOORD"; Munkalap3.D2) függvény a $C:$D$2 értéket adja vissza.
CONTENTS | Bármilyen formázás nélkül visszaadja a hivatkozott cella tartalmát.
TYPE | A cella tartalmának típusát adja vissza. b = blank. üres cella l = label. Szöveg, egy képlet eredménye szöveg formátumban v = value. Érték, egy képlet eredménye szám formátumban
WIDTH | A hivatkozott oszlop szélességét adja eredményül. Az egység az oszlopba az alapértelmezett szöveg alapértelmezett méretében elférő nullák (0) száma.
PREFIX | A hivatkozott cella igazítását adja vissza. ' = igazítás balra vagy bal sorkizárt " = jobbra igazított ^ = középre igazított \ = ismétlés (éppen inaktív)
PROTECT | A cella védelmi állapotát adja vissza. 1 = a cella védett 0 = a cella nem védett
FORMAT | Egy karakterláncot ad vissza, amely a szám formátumot jelöli. , = szám ezreselválasztóval F = szám ezreselválasztó nélkül C = pénznem formátum S = exponenciális jelölés, például 1,234+E56 P = százalék A fenti formátumokban a tizedes elválasztót követő tizedesjegyek száma számként került megadásra. Példa: a #,##0.0 számformátum ,1-et, a 00.000% számformátum pedig P3-at ad eredményül. D1 = HHH-N-ÉÉ, HH-N-ÉÉ és hasonló formátumok D2 = NN-HH D3 = HH-ÉÉ D4 = NN-HH-ÉÉÉÉ ÓÓ:PP:SS D5 = HH-NN D6 = ÓÓ:PP:SS DE/DU D7 = ÓÓ:PP DE/DU D8 = ÓÓ:PP:SS D9 = ÓÓ:PP G = minden más formátum - (Mínusz) a végén = a negatív számok színesen jelennek meg. () (zárójelek) a végén = a formátumkódban egy nyitó zárójel van
COLOR | 1-et ad vissza, ha a negatív számok színesen jelennek meg, egyébként 0-t.
PARENTHESES | 1-et ad vissza, ha a formátumkód nyitó zárójelet ( tartalmaz, egyébként 0-t.

A hivatkozás (beállítások felsorolása) a megvizsgálni kívánt cella pozíciója. Ha a hivatkozás tartomány, akkor a cella a tartomány bal felső sarkába kerül. Ha a hivatkozás nincs megadva, akkor a LibreOfficeDev a képletet tartalmazó cella pozícióját használja. A Microsoft Excel a kurzort tartalmazó cella hivatkozását használja.

## CURRENT

Ez a függvény azt az eredményt adja vissza, amely az őt tartalmazó képlet kiértékelésének idején érvényes volt (más szóval, addig, amíg a kiértékelés eljutott). Főképpen a STYLE() függvénnyel használható együtt a kiválasztott stílusok alkalmazására a cellákra attól függően, hogy mi a cella tartalma.

#### Szintaxis

CURRENT()

#### Példa

=1+2+CURRENT()

A példa eredménye 6. A függvény balról jobbra kerül kiszámításra a következő módon: 1 + 2 egyenlő 3, ami az eredmény addig a pillanatig, amíg CURRENT() utasításhoz ér a feldolgozás; a CURRENT() ezért 3-at ad, amit hozzáadva az eredeti 3-hoz 6-ot kapunk.

=A2+B2+STYLE(IF(CURRENT()>10;"Red";"Default"))

A példa eredménye A2 + B2 (a STYLE itt 0-t ad vissza). Ha ez az összeg nagyobb, mint 10, akkor a cellára a Piros stílus kerül alkalmazásra. Részletesebb magyarázatért lásd a STYLE függvényt.

="zi"&CURRENT()

A példa a „zizi” szót adja vissza.

#### Technikai információk

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.CURRENT

## FORMULA

Egy képletet tartalmazó cella képletét adja vissza szövegként.

This function is always recalculated whenever a recalculation occurs.

#### Szintaxis

FORMULA(hivatkozás)

A hivatkozás egy képletet tartalmazó cellára vonatkozó hivatkozás.

Érvénytelen hivatkozás, illetve képletet nem tartalmazó cellára hivatkozás #HIÁNYZIK hibaértéket eredményez.

#### Példa

Ha az A8 cella a =SZUM(1;2;3) képletet tartalmazza, akkor

a =FORMULA(A8) a „=SZUM(1;2;3)” szöveget adja vissza (az idézőjelek nélkül).

## HAHIÁNYZIK

Returns the value if the cell does not contain the #N/A (value not available) error value, or the alternative value if it does.

Ez a funkció a LibreOfficeDev 4.0 óta érhető el.

#### Szintaxis

HAHIÁNYZIK(érték; alternatív_érték)

Az érték a visszaadni kívánt érték, illetve kifejezés, ha az nem azonos vagy #HIÁNYZIK hibát eredményez.

Az alternatív_érték a visszaadni kívánt érték vagy kifejezés, ha az érték kifejezése vagy értéke azonos vagy #HIÁNYZIK hibát eredményez.

#### Példa

A =HAHIÁNYZIK(D3;D4) visszaadja a D3 értékét, ha a D3 nem eredményez #HIÁNYZIK hibát, vagy D4-et, ha igen.

## HAHIBA

Returns the value if the cell does not contain an error value, or the alternative value if it does.

Ez a funkció a LibreOfficeDev 4.0 óta érhető el.

#### Szintaxis

HAHIBA(érték; alternatív_érték)

Az érték a visszaadni kívánt érték, illetve kifejezés, ha az nem azonos vagy hibát eredményez.

Az alternatív_érték a visszaadni kívánt érték vagy kifejezés, ha az érték kifejezése vagy értéke azonos vagy hibát eredményez.

#### Példa

Az =HAHIBA(C8;C9), ahol a C8 cella tartalma =1/0, a C9 értékét adja vissza, mert az 1/0 hibás kifejezés.

Az =HAHIBA(C8;C9), ahol a C8 cella tartalma =13, a C8 értékét adja vissza, mert az nem hiba.

## HIÁNYZIK

A #HIÁNYZIK hibaértéket adja vissza.

#### Szintaxis

HIÁNYZIK()

#### Példa

A =HIÁNYZIK() a cella tartalmát #HIÁNYZIK-ra változtatja.

## HIBA.E

Ellenőrzi, hogy történt-e hiba, kivéve a #HIÁNYZIK hibaértéket, és IGAZ vagy HAMIS értéket ad vissza.

Hiba esetén a függvény egy logikai vagy numerikus értéket ad vissza.

#### Szintaxis

HIBA.E(érték)

Az érték tetszőleges érték vagy kifejezés, amelyre vonatkozóan ellenőrzésre kerül, hogy a #HIÁNYZIK hibaértéktől eltérő hibaérték jelen van-e.

#### Példa

Az =HIBA.E(C8), ahol a C8 cella tartalma =1/0, IGAZ értéket ad vissza, mert az 1/0 hibás kifejezés.

Az =HIBA.E(C9), ahol a C9 cella tartalma =HIÁNYZIK(), HAMIS értéket ad vissza, mert a HIBA.E() nem veszi figyelembe a #HIÁNYZIK hibát.

## HIBÁS

Ellenőrzi, hogy történt-e hiba, beleértve a #HIÁNYZIK hibaértéket, és IGAZ vagy HAMIS értéket ad vissza.

Hiba esetén a függvény egy logikai vagy numerikus értéket ad vissza.

#### Szintaxis

HIBÁS(érték)

Az érték a vizsgálandó érték, vagy arra hivatkozik. A HIBÁS() IGAZ értéket ad vissza, ha hiba történt, és HAMIS értéket, ha nem.

#### Példa

Az =HIBÁS(C8), ahol a C8 cella tartalma =1/0, IGAZ értéket ad vissza, mert az 1/0 hibás kifejezés.

Az =HIBÁS(C9), ahol a C9 cella tartalma =HIÁNYZIK(), IGAZ értéket ad vissza.

## HIVATKOZÁS

Megvizsgálja, hogy az argumentum referencia-e. IGAZ értéket ad vissza, ha az argumentum referencia, egyébként HAMIS értéket. Ha a függvény referenciát kap, akkor nem vizsgálja a hivatkozott értéket.

Hiba esetén a függvény egy logikai vagy numerikus értéket ad vissza.

#### Szintaxis

HIVATKOZÁS(érték)

Az érték az az érték, amelyről el akarja dönteni, hogy hivatkozás-e.

#### Példa

A =HIVATKOZÁS(C5) IGAZ eredményt ad vissza, mert a C5 érvényes hivatkozás.

A =HIVATKOZÁS("abcdef") mindig HAMIS eredményt ad vissza, mert szöveg nem lehet hivatkozás.

A =HIVATKOZÁS(4) HAMIS eredményt ad vissza.

A =HIVATKOZÁS(INDIREKT("A6")) IGAZ eredményt ad vissza, mert az INDIREKT olyan függvény, amely hivatkozást ad vissza.

A =HIVATKOZÁS(CÍM(1; 1; 2;"Munkalap2")) HAMIS eredményt ad vissza, mert a CÍM olyan függvény, amely szöveget ad vissza, annak ellenére, hogy hivatkozásnak látszik.

## INFO

Az aktuális munkakörnyezetről ad meghatározott információkat. A függvény egyetlen szöveges argumentumot fogad el, és ettől a paramétertől függően ad vissza adatot.

This function is always recalculated whenever a recalculation occurs.

#### Szintaxis

INFO("típus")

A következő táblázat az INFO függvény típus szöveges paraméterének értékeit és visszatérési értékeit tartalmazza.

A „típus” értéke | Visszatérési érték
--- | ---
"osversion" | Kompatibilitási okokból mindig „Windows (32-bit) NT 5.01”.
"system" | The type of the operating system: "ANDROID" for Google mobile operating system "DRAGONFLY" for DragonFly operating system forked from FreeBSD "EMSCRIPTEN" for browser WebAssembly system "FREEBSD", "OPENBSD" or "NETBSD" for operating systems based on the Berkeley Software Distribution (BSD) "HAIKU" for BeOS compatible operating system "iOS" for Apple mobile operating system "LINUX" for GNU/Linux based operating systems "MACOSX" for Apple Mac OS X "SOLARIS" for Oracle Solaris operating system "WNT" for Microsoft Windows
"release" | A termék kiadási azonosítója, például „300m25(Build:9876)”
"numfile" | Kompatibilitási okokból mindig 1.
"recalc" | Az aktuális képlet-újraszámítási mód, „Automatikus” vagy „Manuális”

Más táblázatkezelő programok esetleg elfogadnak honosított értéket is típus paraméterként, de a LibreOfficeDev Calc csak angol értékeket fogad el.

#### Példa

Az =INFO("release") képlet a LibreOfficeDev kiadási számát adja vissza.

Ha a D5 cellában a system szöveg van, az =INFO(D5) képlet az operációs rendszer típusát adja vissza.

## ISEVEN_ADD

Páros számok ellenőrzése. Ha a szám a kettővel történő osztást követően egész számot ad, akkor a függvény eredményül 1 értéket ad.

Az _ADD vagy _EXCEL2003 végű nevű függvények ugyanazt az eredményt adják, mint a megfelelő Microsoft Excel 2003 függvények az utótag nélkül. A függvények utótag nélküli változatait használva a nemzetközi szabványokon alapuló eredményeket kaphatja.

#### Szintaxis

ISEVEN_ADD(szám)

A szám a vizsgálandó szám.

#### Példa

Az =ISEVEN_ADD(5) a 0 értéket adja vissza.

Az =ISEVEN_ADD(A1) 1-et ad vissza, ha az A1 cella a 2-es számot tartalmazza.

## ISODD_ADD

IGAZ értéket ad vissza, ha a szám 2-vel elosztva nem egész számot eredményez.

Az _ADD vagy _EXCEL2003 végű nevű függvények ugyanazt az eredményt adják, mint a megfelelő Microsoft Excel 2003 függvények az utótag nélkül. A függvények utótag nélküli változatait használva a nemzetközi szabványokon alapuló eredményeket kaphatja.

#### Szintaxis

ISODD_ADD(szám)

A szám a vizsgálandó szám.

#### Példa

Az =ISODD_ADD(5) függvény az 1 értéket adja vissza.

## KÉPLET

IGAZ értéket ad vissza, ha a cella képletet tartalmaz.

Hiba esetén a függvény egy logikai vagy numerikus értéket ad vissza.

#### Szintaxis

KÉPLET(hivatkozás)

A hivatkozás egy cellahivatkozást jelöl, amelyben ellenőrzésre kerül, hogy tartalmaz-e képletet.

#### Példa

Az =KÉPLET(C4) HAMIS eredményt ad vissza, ha a C4 cella az 5-ös számot tartalmazza.

## LOGIKAI

Ellenőrzi, hogy logikai értékről (IGAZ vagy HAMIS) van-e szó.

Ha hiba történik, ez a függvény HAMIS eredményt ad vissza.

#### Szintaxis

LOGIKAI(érték)

IGAZ értéket ad vissza, ha az érték logikai érték (IGAZ vagy HAMIS), egyébként HAMIS értéket ad vissza.

#### Példa

A =LOGIKAI(99) a HAMIS értéket adja vissza, mert a 99 egy szám, nem logikai érték.

A =LOGIKAI(NINCS(D4)) az IGAZ értéket adja vissza a D4 cella tartalmától függetlenül, mert a NINCS() logikai értéket ad vissza.

## NEM.SZÖVEG

Megvizsgálja, hogy a cellatartalom szöveg-e vagy szám-e, és HAMIS értéket ad vissza, ha az szöveg.

Ha hiba történik, ez a függvény IGAZ eredményt ad vissza.

#### Szintaxis

NEM.SZÖVEG(érték)

Az érték tetszőleges érték, amelyről meghatározza, hogy szöveg, szám vagy logikai érték-e.

#### Példa

A =NEM.SZÖVEG(D2) HAMIS eredményt ad vissza, ha a D2 cella az abcdef szöveget tartalmazza.

A =NEM.SZÖVEG(D9) IGAZ eredményt ad vissza, ha a D9 cella a 8-as számot tartalmazza.

## NINCS

IGAZ értéket ad vissza, ha a cella a #HIÁNYZIK (nincs érték) hibaértéket tartalmazza.

Ha hiba történik, ez a függvény HAMIS eredményt ad vissza.

#### Szintaxis

NINCS(érték)

Az érték az ellenőrizni kívánt érték, illetve kifejezés.

#### Példa

A =NINCS(D3) függvény a HAMIS értéket ad vissza.

## PÁRATLANE

IGAZ értéket ad vissza, ha a szám páratlan, HAMIS értéket, ha a szám páros.

#### Szintaxis

PÁRATLANE(érték)

Érték: a vizsgálni kívánt érték.

Ha az érték nem egész, a tizedesvessző után álló számjegyek nem lesznek figyelembe véve. Az érték előjele szintén nem számít.

#### Példa

Az =PÁRATLANE(33) eredménye IGAZ.

Az =PÁRATLANE(48) eredménye HAMIS.

Az =PÁRATLANE(3,999) eredménye IGAZ.

Az =PÁRATLANE(-3,1) eredménye IGAZ.

## PÁROSE

IGAZ értéket ad vissza, ha a szám páros egész, HAMIS értéket, ha páratlan.

#### Szintaxis

PÁROSE(érték)

Érték: a vizsgálni kívánt érték.

Ha az érték nem egész, a tizedesvessző után álló számjegyek nem lesznek figyelembe véve. Az érték előjele szintén nem számít.

#### Példa

Az =PÁROSE(48) eredménye IGAZ.

Az =PÁROSE(33) eredménye HAMIS.

Az =PÁROSE(0) eredménye IGAZ.

Az =PÁROSE(-2,1) eredménye IGAZ.

Az =PÁROSE(3,999) eredménye HAMIS.

## S

Egy adott paraméter számértékét adja vissza. A 0 értéket adja vissza, ha a paraméter szöveges vagy HAMIS.

Ha hiba történik, a függvény a hibaértéket adja vissza.

#### Szintaxis

S(érték)

Az érték a paraméter, ami számmá lesz alakítva. Az S() visszaadja a számértéket, ha tudja. Az IGAZ és HAMIS értékekre 1 és 0 értékeket ad vissza. A szövegre 0-t ad vissza.

#### Példa

Az =S(123) a 123 értéket adja vissza.

Az =S(IGAZ()) az 1 értéket adja vissza.

Az =S(HAMIS()) függvény a 0 értéket adja vissza.

Az =S("abc") függvény a 0 értéket adja vissza.

Az =S(1/0) a #ZÉRÓOSZTÓ! értéket adja vissza.

## SZÁM

IGAZ értéket ad vissza, ha az érték számra hivatkozik.

Hiba esetén a függvény egy logikai vagy numerikus értéket ad vissza.

#### Szintaxis

SZÁM(érték)

Az érték tetszőleges ellenőrizni kívánt kifejezés, amelyre meghatározásra kerül, hogy szám vagy szöveg-e.

#### Példa

A =SZÁM(C3) IGAZ eredményt ad vissza, ha a C3 cella a 4-es számot tartalmazza.

A =SZÁM(C2) HAMIS eredményt ad vissza, ha a C2 cella az abcdef szöveget tartalmazza.

## SZÖVEG.E

IGAZ értéket ad vissza, ha a cella tartalma szövegre hivatkozik.

Ha hiba történik, ez a függvény HAMIS eredményt ad vissza.

#### Szintaxis

SZÖVEG.E(érték)

Az érték az ellenőrizni kívánt érték, szám, logikai érték, illetve hibaérték.

#### Példa

A =SZÖVEG.E(D9) IGAZ eredményt ad vissza, ha a D9 cella az abcdef szöveget tartalmazza.

A =SZÖVEG.E(C3) HAMIS eredményt ad vissza, ha a C3 cella a 3-as számot tartalmazza.

## TÍPUS

Az érték típusát adja vissza, ahol 1 = szám, 2 = szöveg, 4 = logikai, 8 = képlet, 16 = hibaérték, 64 = tömb.

Hiba esetén a függvény egy logikai vagy numerikus értéket ad vissza.

#### Szintaxis

TÍPUS(érték)

Az érték egy konkrét érték, amely adattípusa meghatározásra kerül.

### Példa (lásd a fenti példatáblázatot)

A =TÍPUS(C2) függvény a 2 értéket adja vissza.

A =TÍPUS(D9) függvény az 1 értéket adja vissza.

## ÜRES

IGAZ értéket ad vissza, ha a cella üres. A függvény segítségével meghatározhatja, hogy egy cella tartalma üres-e. A képletet tartalmazó cellák nem számítanak üresnek.

Hiba esetén a függvény egy logikai vagy numerikus értéket ad vissza.

#### Szintaxis

ÜRES(érték)

Az érték az ellenőrizni kívánt tartalom.

#### Példa

Az =ÜRES(D2) függvény a HAMIS értéket adja vissza.

Kapcsolódó témakörök

Függvények kategória szerint