Spis treści
Indeks 🔎︎

# Instrukcja MkDir

Tworzy nowy katalog na nośniku danych.

### Składnia:

    MkDir path

### Parametry:

path: Any string expression that specifies the name and path of the directory to be created. You can also use URL notation.

Jeśli ścieżka nie została określona, katalog jest tworzony w katalogu domyślnym.

### Kody błędów:

5 Nieprawidłowe wywołanie procedury

76 Ścieżka nie została znaleziona

### Przykład:

    Sub ExampleFileIO
    ' Przykład funkcji porządkowania plików
    Const sFile1 As String = "file://c|/autoexec.bat"
    Const sDir1 As String = "file://c|/Temp"
    Const sSubDir1 As String ="Test"
    Const sFile2 As String = "Copied.tmp"
    Const sFile3 As String = "Renamed.tmp"
    Dim sFile As String
        sFile = sDir1 + "/" + sSubDir1
        ChDir( sDir1 )
        If Dir(sSubDir1,16)="" Then ' Czy katalog istnieje?
            MkDir sSubDir1
            MsgBox sFile,0,"Tworzenie katalogu"
        End If
        sFile = sFile + "/" + sFile2
        FileCopy sFile1 , sFile
        MsgBox fSysURL(CurDir()),0,"Bieżący katalog"
        MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"Czas utworzenia"
        MsgBox sFile & Chr(13)& FileLen( sFile ),0,"Długość pliku"
        MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"Atrybuty pliku"
        Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
        ' Zmiana nazwy w tym samym katalogu
        sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
        SetAttr( sFile, 0 ) 'Usunięcie wszystkich atrybutów
        MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"Nowe atrybuty pliku"
        Kill sFile
        RmDir sDir1 + "/" + sSubDir1
    End Sub

    ' Konwertuje ścieżkę z postaci systemowej do URL
    Function fSysURL( fSysFp As String ) As String
    Dim iPos As String
        iPos = 1
        iPos = Instr(iPos,fSysFp, getPathSeparator())
        Do While iPos > 0
            Mid( fSysFp, iPos , 1,"/")
            iPos = Instr(iPos+1,fSysFp, getPathSeparator())
        Loop
        ' dwukropek z DOS
        iPos = Instr(1,fSysFp,":")
        If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
        fSysURL = "file://" & fSysFp
    End Function