Spis treści
Indeks 🔎︎

# Funkcje bazy danych

### Przegląd

Dwanaście funkcji w kategorii Baza danych pomaga analizować prostą bazę danych, która zajmuje prostokątny obszar arkusza kalkulacyjnego zawierający kolumny i wiersze, z danymi zorganizowanymi jako jeden wiersz dla każdego rekordu.Główka komórki każdej kolumny wyświetla nazwę kolumny, a nazwa ta zwykle odzwierciedla zawartość każdej komórki w tej kolumnie.

Funkcje w kategorii Baza danych przyjmują trzy następujące argumenty:

1. Baza danych. Zakres komórek bazy danych.

2. Pole bazy danych. Kolumna zawierająca dane, które mają być użyte w obliczeniach funkcji.

3. Kryteria wyszukiwania. Zakres komórek oddzielnego obszaru arkusza kalkulacyjnego zawierającego kryteria wyszukiwania.

Argumenty te opisano dokładniej poniżej.

Wszystkie funkcje mają tę samą ogólną koncepcję działania. Pierwszym logicznym krokiem jest użycie określonych Kryteriów wyszukiwania w celu zidentyfikowania podzbioru rekordów w Bazie danych, które mają być użyte podczas kolejnych obliczeń. Drugim krokiem jest wyodrębnienie wartości danych i wykonanie obliczeń związanych z określoną funkcją (średnia, suma, iloczyn itd.). Przetwarzane wartości to wartości w kolumnie Pole bazy danych wybranych rekordów.

Calc traktuje daty i wartości logiczne (PRAWDA i FAŁSZ) jako liczbowe podczas wykonywania obliczeń za pomocą tych funkcji.

### Argumenty funkcji bazy danych

Następujące definicje argumentów mają zastosowanie do wszystkich funkcji w kategorii Baza danych:

1. Argument bazy danych

   Baza danych określa zakres komórek zajmowanych przez tabelę bazy danych. Pierwszy wiersz zakresu zawiera nazwy pól, a kolejne wiersze to rekordy z odpowiadającymi im wartościami pól.

   Jednym ze sposobów zdefiniowania zakresu komórek jest wprowadzenie odwołania do komórki w lewym górnym rogu, po którym następuje dwukropek (:), a następnie odwołanie do komórki w prawym dolnym rogu. Przykładem może być A1:E10.

   Argument Baza danych może być również określony poprzez przekazanie nazwy nazwanego zakresu lub zakresu bazy danych. Użycie znaczącej nazwy do zdefiniowania zakresu komórek może poprawić czytelność formuły i konserwację dokumentów. Jeśli nazwa nie pasuje do nazwy zdefiniowanego zakresu, program Calc zgłasza błąd #NAZWA?.

   Inne błędy, które mogą być zgłaszane w wyniku podania nieprawidłowego argumentu Baza danych, to #ARG! i Błąd:504 (błąd w liście parametrów).

2. Argument Pola bazy danych

   Pole bazy danych określa kolumnę, której funkcja użyje do obliczeń po zastosowaniu kryteriów wyszukiwania i wybraniu wierszy danych. Nie jest to związane z kryteriami wyszukiwania.

   Podaj argument Pole bazy danych w jeden z następujących sposobów:

   - Wprowadzając odwołanie do komórki nagłówka w obszarze Baza danych. Alternatywnie, jeśli komórce nadano znaczącą nazwę jako nazwany zakres lub zakres bazy danych, wprowadź tę nazwę. Jeśli nazwa nie pasuje do nazwy zdefiniowanego zakresu, program Calc zgłasza błąd #NAZWA?. Jeśli nazwa jest poprawna, ale nie odpowiada tylko jednej komórce, Calc zgłasza Błąd:504 (błąd na liście parametrów).

   - Wprowadzając liczbę określającą kolumnę w obszarze Baza danych, zaczynając od 1. Na przykład, jeśli Baza danych zajmuje zakres komórek D6:H123, wprowadź 3, aby wskazać komórka nagłówka w F6. Calc oczekuje wartości całkowitej mieszczącej się w przedziale od 1 do liczby kolumn zdefiniowanych w Bazie danych i ignoruje wszelkie cyfry po przecinku. Jeśli wartość jest mniejsza niż 1, Calc zgłasza Błąd:504 (błąd na liście parametrów). Jeśli wartość jest większa niż liczba kolumn w Bazie danych, program Calc zgłasza #ARG!.

   - Wpisując dosłowną nazwę główki kolumny z pierwszego wiersza zakresu Baza danych, umieszczając nazwę główki w cudzysłowie. Na przykład „Odległość do szkoły”. Jeśli ciąg znaków nie pasuje do jednej z główek kolumn obszaru Baza danych, program Calc zgłasza błąd Błąd:504 (błąd na liście parametrów). Możesz także podać odwołanie do dowolnej komórki (poza obszarami Baza danych i Kryteria wyszukiwania), która zawiera wymagany ciąg.

   Argument Pole bazy danych jest opcjonalny dla funkcji BD.ILE.REKORDÓW i BD.ILE.REKORDÓW.A, ale jest wymagany dla pozostałych dziesięciu funkcji bazy danych.

3. Argument Kryteriów wyszukiwania

   Kryteria wyszukiwania określa zakres komórek zawierających kryteria wyszukiwania. Podobnie jak Baza danych, jej pierwszy wiersz to także nazwy pól, a kolejne wiersze to warunki dla powiązanych pól. Obszary Baza danych i Kryteria wyszukiwania nie muszą przylegać do siebie ani znajdować się na tym samym arkuszu.

   Jednym ze sposobów zdefiniowania zakresu komórek jest wprowadzenie odwołania do komórki w lewym górnym rogu, po którym następuje dwukropek (:), a następnie odwołanie do komórki w prawym dolnym rogu. Na przykład A13:B14. Zakres komórek można również określić, przekazując nazwę zdefiniowanego nazwanego zakresu lub zakresu bazy danych. Jeśli nazwa nie pasuje do nazwy zdefiniowanego zakresu, program Calc zgłasza błąd #NAZWA?.

   Błąd:504 (błąd na liście parametrów) może być również zgłaszany jako wynik nieprawidłowego argumentu Kryteria wyszukiwania.

   Zawartość obszaru Kryteria wyszukiwania została opisana bardziej szczegółowo w następnej sekcji.

### Definiowanie kryteriów wyszukiwania

Liczba kolumn zajmowanych przez obszar Kryteria wyszukiwania nie musi być taka sama jak szerokość obszaru Baza danych. Wszystkie nagłówki pojawiające się w pierwszym wierszu Kryteriów wyszukiwania muszą być identyczne z nagłówkami w pierwszym wierszu Bazy danych. Jednak nie wszystkie nagłówki w Bazie danych muszą pojawiać się w pierwszym wierszu Kryteriów wyszukiwania, podczas gdy nagłówek w Bazie danych może pojawić się wiele razy w pierwszym wierszu wiersz Kryteria wyszukiwania.

Kryteria wyszukiwania są wprowadzane do komórek drugiego i kolejnych wierszy obszaru Kryteria wyszukiwania, poniżej wiersza zawierającego nagłówki. Puste komórki w obszarze Kryteria wyszukiwania są ignorowane.

Utwórz kryteria w komórkach obszaru Kryteria wyszukiwania, używając operatorów porównania <, <=, =, <>, >=, oraz >. = jest przyjmowane, jeśli komórka nie jest pusta, ale nie zaczyna się od operatora porównania.

Jeśli wpiszesz kilka kryteriów w jednym wierszu, zostaną one połączone operatorem I. Jeśli wpiszesz kilka kryteriów w różnych wierszach, zostaną one połączone przez operator LUB.

Kryteria można tworzyć za pomocą symboli wieloznacznych, pod warunkiem że zostały one włączone za pomocą opcji Włącz symbole wieloznaczne w formułach na stronie okna dialogowego LibreOfficeDev - PreferencjeNarzędzia - Opcje - LibreOfficeDev Calc - Oblicz. Jeśli dla arkusza kalkulacyjnego ważna jest interoperacyjność z programem Microsoft Excel, ta opcja powinna być włączona.

Jeszcze potężniejsze kryteria można tworzyć za pomocą wyrażeń regularnych, pod warunkiem, że wyrażenia regularne zostały włączone za pomocą opcji Włącz wyrażenia regularne w formułach na stronie okna dialogowego LibreOfficeDev - PreferencjeNarzędzia - Opcje - LibreOfficeDev Calc - Oblicz.

W przypadku korzystania z funkcji, w których jeden lub więcej argumentów to ciągi kryteriów wyszukiwania reprezentujące wyrażenie regularne, pierwszą próbą jest przekonwertowanie kryteriów ciągu na liczby. Na przykład „.0” zostanie przekonwertowane na 0,0 i tak dalej. Jeśli się powiedzie, dopasowanie nie będzie dopasowaniem wyrażenia regularnego, ale dopasowaniem liczbowym. Jednak po przełączeniu na ustawienia regionalne, w których separatorem dziesiętnym nie jest kropka, konwersja wyrażeń regularnych działa. Aby wymusić ocenę wyrażenia regularnego zamiast wyrażenia liczbowego, użyj wyrażenia, którego nie można błędnie odczytać jako liczbowego, takiego jak „.[0]”, „.\0” lub „(?i).0”.

Another setting that affects how the search criteria are handled is the Search criteria = and <> must apply to whole cells option on the LibreOfficeDev - PreferencesTools - Options - LibreOfficeDev Calc - Calculate dialog. This option controls whether the search criteria you set for the Database functions must match the whole cell exactly. When interoperability with Microsoft Excel is important for your spreadsheet, this option should be enabled.

### Przykłady użycia funkcji bazy danych

Poniższa tabela zawiera przykładową tabelę bazy danych, która służy do demonstrowania sposobu korzystania z funkcji w kategorii Baza danych. Zakres komórek A1:E10 zawiera fikcyjne informacje o gościach zaproszonych na przyjęcie urodzinowe Jana. Dla każdego gościa podawane są następujące informacje - imię, klasa szkolna, wiek w latach, odległość do szkoły w metrach, waga w kilogramach.

| A | B | C | D | E
1 | Imię | Klasa | Wiek | Dystans | Waga
2 | Andrzej | 3 | 9 | 150 | 40
3 | Beata | 4 | 10 | 1000 | 42
4 | Czesław | 3 | 10 | 300 | 51
5 | Daniel | 5 | 11 | 1200 | 48
6 | Ewa | 2 | 8 | 650 | 33
7 | Franek | 2 | 7 | 300 | 42
8 | Greta | 1 | 7 | 200 | 36
9 | Henryk | 3 | 9 | 1200 | 44
10 | Irena | 2 | 8 | 1000 | 42
11 |  |  |  |  |

Poniższe sześć przykładów wykorzystuje powyższą tabelę bazy danych w połączeniu z różnymi obszarami kryteriów wyszukiwania.

#### Przykład 1

| A | B | C | D | E
12 | Imię | Klasa | Wiek | Dystans | Waga
13 |  |  |  | >600 |
14 |  |  |  |  |

Tak jak w tym prostym przykładzie, czasami pożądane (ale nie niezbędne) jest umieszczenie obszaru kryteriów wyszukiwania bezpośrednio pod tabelą bazy danych, z kolumnami obu obszarów ustawionymi pionowo. Puste wpisy w obszarze kryteriów wyszukiwania są ignorowane. Korzystając z powyższej przykładowej tabeli bazy danych i tego obszaru kryteriów wyszukiwania, wstaw formułę =BD.ILE.REKORDÓW(A1:E10;;A12:E14) do pustej komórki w innym miejscu arkusza, aby policzyć, jak wielu gości Jana dojeżdża do szkoły dalej niż 600 metrów. Zwracana jest wartość 5 (licząc Beatę, Daniela, Ewę, Henryka i Irenę).

Zauważ również, że formuła =BD.ILE.REKORDÓW(A1:E10;;D12:D13) zwraca dokładnie taką samą wartość, co pokazuje, że wystarczy, aby obszar kryteriów wyszukiwania zawierał odpowiednie nagłówki kolumn.

#### Przykład 2

| A | B | C | D | E
12 |  | Wiek | Klasa |  |
13 |  | >7 | 2 |  |
14 |  |  |  |  |

W tym przykładzie obszar kryteriów wyszukiwania zawiera tylko dwa nagłówki, które nie są wyrównane w pionie z odpowiednimi nagłówkami w przykładowej tabeli bazy danych. Ponieważ w tym samym rzędzie znajdują się dwa warunki, są one połączone operatorem I. Korzystając z powyższej przykładowej tabeli bazy danych i tego obszaru kryteriów wyszukiwania, wstaw formułę =BD.ILE.REKORDÓW(A1:E10;;B12:C13) do pustej komórki w innym miejscu arkusza, aby policzyć, jak wielu gości Jana jest w klasie 2 i starszych niż 7 lat. Zwracana jest wartość 2 (licząc Ewę i Irenę).

#### Przykład 3

| A | B | C | D | E
12 |  | Wiek |  |  |
13 |  | 9 |  |  |
14 |  | 10 |  |  |

W tym przykładzie obszar kryteriów wyszukiwania zawiera tylko jeden nagłówek. Ponieważ w kolejnych wierszach występują dwa warunki, są one połączone przez operator I. Korzystając z powyższej przykładowej tabeli bazy danych i tego obszaru kryteriów wyszukiwania, wstaw formułę =BD.ILE.REKORDÓW(A1:E10;;B12:B14) do pustej komórki w innym miejscu arkusza, aby policzyć, jak wielu gości Jana ma 9 lub 10 lat. Zwracana jest wartość 4 (licząc Andrzeja, Beatę, Czesława i Henryka).

#### Przykład 4

| A | B | C | D | E
12 |  | Wiek | Wiek |  |
13 |  | >=8 | <=10 |  |
14 |  |  |  |  |

W tym przykładzie obszar kryteriów wyszukiwania zawiera dwa wystąpienia tego samego nagłówka. Ponieważ w tym samym rzędzie znajdują się dwa warunki, są one połączone operatorem I. Korzystając z powyższej przykładowej tabeli bazy danych i tego obszaru kryteriów wyszukiwania, wstaw formułę =BD.ILE.REKORDÓW(A1:E10;;B12:C13) do pustej komórki w innym miejscu arkusza, aby policzyć, jak wielu gości Jan ma od 8 do 10 lat (włącznie). Zwracana jest wartość 6 (licząc Andrzeja, Beatę, Czesława, Ewę, Henryka i Irenę).

#### Przykład 5

| A | B | C | D | E
12 | Imię |  |  |  |
13 | F* |  |  |  |
14 |  |  |  |  |

Ten prosty przykład pokazuje użycie symboli wieloznacznych. Aby ten przykład działał zgodnie z oczekiwaniami, wybierz opcję włączania symboli wieloznacznych w LibreOfficeDev - PreferencjeNarzędzia - Opcje - LibreOfficeDev Calc - Oblicz. Korzystając z powyższej przykładowej tabeli bazy danych i tego obszaru kryteriów wyszukiwania, wstaw formułę =BD.ILE.REKORDÓW(A1:E10;;A12:A13) do pustej komórki w innym miejscu arkusza, aby policzyć, jak wielu gości Jana ma imiona zaczynające się na literę „F”. Zwracana jest wartość 1 (licząc Franka).

#### Przykład 6

| A | B | C | D | E
12 | Imię |  |  |  |
13 | [ABC].* |  |  |  |
14 |  |  |  |  |

Ten prosty przykład pokazuje użycie wyrażeń regularnych. Aby ten przykład działał zgodnie z oczekiwaniami, włącz wyrażenia regularne w % PRODUCTNAME - PreferencjeNarzędzia - Opcje - LibreOfficeDev Calc - Oblicz. Korzystając z powyższej przykładowej tabeli bazy danych i tego obszaru kryteriów wyszukiwania, wstaw formułę =BD.ILE.REKORDÓW(A1:E10;;A12:A13) do pustej komórki w innym miejscu arkusza, aby policzyć, jak wielu gości Jana ma imiona zaczynające się na litery „A”, „B” lub „C”. Zwracana jest wartość 3 (licząc Andrzeja, Beatę i Czesława).

## BD.ILE.REKORDÓW

BD.ILE.REKORDÓW zlicza liczbę komórek (pól) określonej kolumny, które zawierają wartości liczbowe, dla wszystkich wierszy (rekordów bazy danych) spełniających określone kryteria wyszukiwania. Jeśli jednak żadna kolumna nie jest określona, funkcja BD.ILE.REKORDÓW zwraca liczbę wszystkich rekordów spełniających określone kryteria wyszukiwania, niezależnie od ich zawartości.

#### Składnia

BD.ILE.REKORDÓW(baza_danych; [pole_bazy_danych]; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki D13, która powinna zawierać „>600” (to kryterium wyszukiwania spowoduje dopasowanie rekordów w tabeli bazy danych, które mają wartość większą niż 600 w kolumnie Dystans).

Wstaw formułę =BD.ILE.REKORDÓW(A1:E10;; A12:E13) w pustej komórce w innym miejscu arkusza, aby obliczyć, ilu gości na przyjęciu Jana ma do szkoły więcej niż 600 metrów. Zwracana jest wartość 5.

Ten sam wynik zostanie uzyskany, jeśli użyjesz formuły =BD.ILE.REKORDÓW(A1:E10; "Dystans"; A12:E13), ponieważ wszystkie wpisy w kolumnie Dystans są liczbowe. Jeśli jednak użyjesz formuły =BD.ILE.REKORDÓW(A1:E10; "Imię"; A12:E13), zostanie zwrócona wartość 0, ponieważ wszystkie wpisy w kolumnie Imię są nieliczbowe.

## BD.ILE.REKORDÓW.A

BD.ILE.REKORDÓW.A zlicza liczbę komórek (pól) określonej kolumny, które nie są puste, dla wszystkich wierszy (rekordów bazy danych) spełniających określone kryteria wyszukiwania. Puste komórki określonej kolumny nie są liczone. Jeśli jednak nie określono żadnej kolumny, funkcja BD.ILE.REKORDÓW.A zwraca liczbę wszystkich rekordów spełniających określone kryteria wyszukiwania, niezależnie od ich zawartości.

#### Składnia

BD.ILE.REKORDÓW.A(baza_danych; [pole_bazy_danych]; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki D13, która powinna zawierać „>600” (to kryterium wyszukiwania spowoduje dopasowanie rekordów w tabeli bazy danych, które mają wartość większą niż 600 w kolumnie Dystans).

Wstaw formułę =BD.ILE.REKORDÓW.A(A1:E10;; A12:E13) w pustej komórce w innym miejscu arkusza, aby obliczyć, ilu gości na przyjęciu Jana ma do szkoły więcej niż 600 metrów. Zwracana jest wartość 5.

Ten sam wynik zostanie uzyskany, jeśli użyjesz formuły =BD.ILE.REKORDÓW.A(A1:E10; "Dystans"; A12:E13) lub formuły =BD.ILE.REKORDÓW.A(A1:E10; "Nazwa"; A12 :E13). Ten ostatni przypadek odzwierciedla, że w przeciwieństwie do BD.ILE.REKORDÓW funkcja BD.ILE.REKORDÓW.A zlicza zarówno wartości liczbowe, jak i alfanumeryczne w kolumnie wskazanej przez argument Pole bazy danych.

## BD.ILOCZYN

BD.ILOCZYN oblicza iloczyn wszystkich wartości liczbowych w komórkach (polach) określonej kolumny dla wszystkich wierszy (rekordów bazy danych), które spełniają określone kryteria wyszukiwania. Puste komórki lub komórki zawierające znaki nienumeryczne nie są uwzględniane.

Zwraca 0, jeśli nie znaleziono żadnych dopasowań lub jeśli w komórkach określonej kolumny dla pasujących rekordów nie ma wartości liczbowych.

#### Składnia

BD.ILOCZYN(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki C13, która powinna zawierać „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.ILOCZYN(A1:E10; "Wiek"; A12:E13) do pustej komórki w innym miejscu arkusza, aby obliczyć iloczyn wieku gości na przyjęciu Jana w latach. Zwracana jest wartość 279417600.

## BD.MAKS

BD.MAKS oblicza maksymalną wartość w komórkach (polach) określonej kolumny, które zawierają wartości liczbowe, dla wszystkich wierszy (rekordów bazy danych) spełniających określone kryteria wyszukiwania. Puste komórki lub komórki zawierające znaki inne niż numeryczne nie są uwzględniane.

Zwraca 0, jeśli nie znaleziono żadnych dopasowań lub jeśli nie ma niezerowych wartości liczbowych w komórkach określonej kolumny dla pasujących rekordów.

#### Składnia

BD.MAKS(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki D13, która powinna zawierać „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.MAKS(A1:E10; "Dystans"; A12:E13) do pustej komórki w innym miejscu arkusza, aby znaleźć maksymalną odległość w metrach, jaką każdy z gości Jana pokonuje do szkoły. Zwracana jest wartość 1200.

## BD.MIN

BD.MIN oblicza minimalną wartość w komórkach (polach) określonej kolumny, które zawierają wartości liczbowe, dla wszystkich wierszy (rekordów bazy danych) spełniających określone kryteria wyszukiwania. Puste komórki lub komórki zawierające znaki inne niż numeryczne nie są uwzględniane.

Zwraca 0, jeśli nie znaleziono żadnych dopasowań lub jeśli nie ma niezerowych wartości liczbowych w komórkach określonej kolumny dla pasujących rekordów.

#### Składnia

BD.MIN(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami nagłówka tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki D13, która powinna zawierać „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.MIN(A1:E10; "Dystans"; A12:E13) do pustej komórki w innym miejscu arkusza, aby znaleźć minimalną odległość w metrach, którą każdy z gości Jana przebywa do szkoły. Zwracana jest wartość 150.

## BD.ODCH.STANDARD

BD.ODCH.STANDARD oblicza odchylenie standardowe próbki na podstawie wartości liczbowych w komórkach (polach) określonej kolumny dla wszystkich wierszy (rekordów bazy danych), które pasują do określonych kryteriów wyszukiwania.Wartości nieliczbowe są ignorowane.

Zwraca błąd #LICZBA!, jeśli dokładnie jeden rekord pasuje do określonych kryteriów wyszukiwania lub jeśli w komórkach określonej kolumny dla pasujących rekordów jest tylko jedna wartość liczbowa.

Zwraca 0, jeśli nie znaleziono żadnych dopasowań lub jeśli w komórkach określonej kolumny dla pasujących rekordów nie ma wartości liczbowych.

#### Składnia

BD.ODCH.STANDARD(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:D13 są puste i że komórka E13 zawiera „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.ODCH.STANDARD(A1:E10; "Waga"; A12:E13) w pustej komórce w innym miejscu arkusza, aby obliczyć przykładowe odchylenie standardowe wagi gości w kg na przyjęciu Jana. Zwracana jest wartość 5,5.

## BD.ODCH.STANDARD.POPUL

BD.ODCH.STANDARD oblicza odchylenie standardowe populacji na podstawie wartości liczbowych w komórkach (polach) określonej kolumny dla wszystkich wierszy (rekordów bazy danych), które pasują do określonych kryteriów wyszukiwania. Wartości nieliczbowe są ignorowane.

Zwraca błąd #LICZBA!, jeśli żadne rekordy nie pasują do określonych kryteriów wyszukiwania lub jeśli w komórkach określonej kolumny dla pasujących rekordów nie ma wartości liczbowych.

#### Składnia

BD.ODCH.STANDARD.POPUL(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:D13 są puste i że komórka E13 zawiera „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.ODCH.STANDARD.POPUL(A1:E10; "Waga"; A12:E13) do pustej komórki w innym miejscu arkusza, aby obliczyć odchylenie standardowe populacji wag w kg gości na przyjęciu Jana. Zwracana jest wartość 5,18545.

## BD.POLE

BD.POLE zwraca zawartość komórki (pola) określonej kolumny dla pojedynczego wiersza (rekordu bazy danych), który spełnia określone kryteria wyszukiwania.

Calc zgłasza Błąd:502 (nieprawidłowy argument), jeśli znaleziono wiele dopasowań lub błąd #ARG! (niewłaściwy typ danych), jeśli nie znaleziono żadnych dopasowań. Błąd #WARTOŚĆ! jest również zgłaszany, jeśli zostanie znalezione pojedyncze dopasowanie, ale odpowiednia komórka jest pusta.

#### Składnia

BD.POLE(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki C13, która powinna zawierać „11” (to kryterium wyszukiwania będzie odpowiadać rekordom w tabeli bazy danych, które mają wartość 11 w kolumnie Wiek).

Wstaw formułę =BD.POLE(A1:E10; "Imię"; A12:E13) do pustej komórki w innym miejscu arkusza, aby znaleźć imię gościa na przyjęciu Jana, który ma 11 lat. Imię Daniel jest zwrócone.

Jeśli zmienisz wartość w komórce C13 na „10”, formuła =BD.POLE(A1:E10; "Imię"; A12:E13) zwróci błąd nieprawidłowego argumentu (Błąd:502). Odzwierciedla, że wiele rekordów spełnia określone kryterium (zarówno Beata, jak i Czesław mają po 10 lat).

## BD.SUMA

BD.SUMA oblicza sumę wszystkich wartości liczbowych w komórkach (polach) określonej kolumny dla wszystkich wierszy (rekordów bazy danych), które spełniają określone kryteria wyszukiwania. Puste komórki lub komórki zawierające znaki nienumeryczne nie są uwzględniane.

Zwraca 0, jeśli nie znaleziono żadnych dopasowań lub jeśli w komórkach określonej kolumny dla pasujących rekordów nie ma wartości liczbowych.

#### Składnia

BD.SUMA(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki D13, która powinna zawierać „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.SUMA(A1:E10; "Dystans"; A12:E13) w pustej komórce w innym miejscu arkusza, aby znaleźć całkowitą odległość w metrach, którą wszyscy goście z imprezy Jana pokonują do szkoły. Zwracana jest wartość 6000.

## BD.ŚREDNIA

BD.ŚREDNIA oblicza średnią wartości liczbowych w komórkach (polach) określonej kolumny dla wszystkich wierszy (rekordów bazy danych), które spełniają określone kryteria wyszukiwania. Wartości nieliczbowe w te komórki są ignorowane.

Zwraca błąd #DZIEL/0!, jeśli żadne rekordy nie pasują do określonych kryteriów wyszukiwania lub jeśli w komórkach określonej kolumny dla pasujących rekordów nie ma wartości liczbowych.

#### Składnia

BD.ŚREDNIA(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki D13, która powinna zawierać „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.ŚREDNIA(A1:E10; "Dystans"; A12:E13) w pustej komórce w innym miejscu arkusza, aby obliczyć średnią odległość w metrach przebytą do szkoły przez gości na przyjęciu Jana. Zwracana jest wartość 666,67.

## BD.WARIANCJA

BD.WARIANCJA oblicza wariancję próbki na podstawie wartości liczbowych w komórkach (polach) określonej kolumny dla wszystkich wierszy (rekordów bazy danych) spełniających określone kryteria wyszukiwania. Nieliczbowe wartości są ignorowane.

Zwraca błąd #LICZBA!, jeśli dokładnie jeden rekord pasuje do określonych kryteriów wyszukiwania lub jeśli w komórkach określonej kolumny dla pasujących rekordów jest tylko jedna wartość liczbowa.

Zwraca 0, jeśli nie znaleziono żadnych dopasowań lub jeśli w komórkach określonej kolumny dla pasujących rekordów nie ma wartości liczbowych.

#### Składnia

BD.WARIANCJA(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki D13, która powinna zawierać „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.WARIANCJA(A1:E10; "Dystans"; A12:E13) w pustej komórce w innym miejscu arkusza, aby znaleźć przykładową wariancję odległości w metrach, jaką goście Jana pokonują do szkoły . Zwracana jest wartość 193125.

## BD.WARIANCJA.POPUL

BD.WARIANCJA.POPUL oblicza zmienność populacji na podstawie wartości liczbowych w komórkach (polach) określonej kolumny dla wszystkich wierszy (rekordów bazy danych) spełniających określone kryteria wyszukiwania. Nieliczbowe wartości są ignorowane.

Zwraca błąd #LICZBA!, jeśli żadne rekordy nie pasują do określonych kryteriów wyszukiwania lub jeśli w komórkach określonej kolumny dla pasujących rekordów nie ma wartości liczbowych.

#### Składnia

BD.WARIANCJA.POPUL(baza_danych; pole_bazy_danych; kryteria_wyszukiwania)

#### Przykład

Przykładowa tabela bazy danych zawierająca informacje o gościach zaproszonych na przyjęcie urodzinowe Jana (opisane powyżej) powinna zajmować komórki A1:E10. Zawartość komórek A12:E12 powinna być identyczna z etykietami główki tabeli bazy danych w komórkach A1:E1. Upewnij się, że komórki A13:E13 są puste, z wyjątkiem komórki D13, która powinna zawierać „>0” (to kryterium wyszukiwania ma na celu dopasowanie wszystkich rekordów w tabeli bazy danych).

Wstaw formułę =BD.WARIANCJA.POPUL(A1:E10; "Dystans"; A12:E13) do pustej komórki w innym miejscu arkusza, aby znaleźć wariancję populacyjną odległości w metrach, jaką goście Jana pokonują do szkoły . Zwracana jest wartość 171666,67.

Tematy pokrewne

Funkcje według kategorii