Third Party Libraries | Qt 5.15

- Qt 5.15
- Third Party Libraries
- Qt 5.15.17 Reference Documentation

# Third Party Libraries

Using a third-party library with Qt is a simple process. Suppose you know of a cross-platform library that accepts audio samples of a cat's meows and translates them into English words. This library is named `CatWhisperer`, and has several files that it provides as part of its library. Your project, `MyQtApp`, stores these files in a folder named `3rdparty`:

- MyQtApp/
  - MyQtApp.pro
  - src/
    - main.cpp
  - 3rdparty/
    - CatWhisperer
      - include/
        - CatWhisperer.h
      - lib/
        - libCatWhisperer.so
        - CatWhisperer.lib
      - bin/
        - CatWhisperer.dll

To use the `CatWhisperer` library in `MyQtApp`, `qmake` requires the location and names of the `CatWhisperer` libraries. Optionally, you can also:

- Provide the location of the `CatWhisperer` source code so that you don't have to type out the full path to each file when you include them in your own code.
- Choose the destination in which the `MyQtApp` executable will be created.

The information above is provided in the `.pro` file, so that `qmake` can parse it and produce makefiles. Makefiles contain all the information needed by your compiler and linker to produce output, whether it is an executable, another library file, etc. The next sections explain the syntax with which `qmake` expects you to provide this information.

## Source Code

To be able to write

     #include <CatWhisperer.h>

instead of

     #include <3rdparty/CatWhisperer/include/CatWhisperer.h>

you can provide the path to the `CatWhisperer` `include` directory, using the INCLUDEPATH variable:

     INCLUDEPATH += 3rdparty/CatWhisperer/include

## Library Files

To let `qmake` know where to find the `CatWhisperer` library files, use the LIBS variable:

     LIBS += -L"3rdparty/CatWhisperer/lib" -lCatWhisperer

The first part of the expression lets the linker know in which directory it should look for the library files. The double quotes are only necessary when the path contains spaces, so we could have omitted them in this example.

The second part tells the linker which libraries to link against. We have two different library files for UNIX platforms and Windows, respectively: `libCatWhisperer.so` and `CatWhisperer.lib`. It is not necessary to specify the `.lib` extension, nor the `lib` prefix (on UNIX platforms).

## Destination Directory

By default, `qmake` creates the executable in the same directory as the `.pro` file. We can choose our own directory using the DESTDIR variable:

     DESTDIR = bin

That's it! You can now use the `CatWhisperer` library in your project. The final `.pro` file looks like this:

     TARGET = MyQtApp

     TEMPLATE = app

     INCLUDEPATH += 3rdparty/CatWhisperer/include

     SOURCES += src/main.cpp

     LIBS += -L"3rdparty/CatWhisperer/lib" -lCatWhisperer

See also qmake Manual and Qt Creator: Adding Libraries to Projects.