
<compile>
	::sys<args #x>
	::sys<nth #inputfile #x 1>
	::sys<suffix #outputfile #inputfile c>
	<print inputfile #inputfile>
	<print outputfile #outputfile>
	::sys<openw #outputfile
		::sys<openr #inputfile <TinyPython>>>
	;


<TinyPython>				<print "#include <stdio.h>">
					<print "int main() {">
					<print "int a,b,c,d,e,f,g,h,i,j,k,l,m;">
					<print "int n,o,p,q,r,s,t,u,v,w,x,y,z;">
					<setVar exline 1>
		{
					<SKIPSPACE>
		  			<INDENT 0>
		  <プログラム> 
		}
					<SKIPSPACE>
					<x <errormsg "indent error">>
		  			<INDENT 0>
		<EOF>			<print "exit(0);">
					<print "}">
		;

<プログラム>
		  <制御文>
		| 
		  <プログラム文>
		;

<プログラム文>
		[<実行文> { ";" <実行文>}] [<コメント>] <CR>;

<ブロック>
		":"			<INDENT #n0>
					<SKIPSPACE>
					<INDENT #n>
					<print "{">
		{
					<SKIPSPACE>
					<INDENT #n>
		  <プログラム>
		}
					<SKIPSPACE>
					<INDENT #n0>
					<x <errormsg "indent error">>
					<print "}">
		;

<制御文>	( <if文> | <while文> | <for文> )
					<setVar exline 
						<_ = ::sys <line #l>+1>>;

<実行文>	( <print文> | <代入文>)
					<setVar exline 
						<_ = ::sys <line #l>+1>>;


<if文>          "if"	 		<x <errormsg "if文にエラー">>
					<printf "if (">
		<条件式>		<printf ") ">
		<ブロック> 
		[ 
			"else"   	<x <errormsg "else文にエラー">>
			 		<printf "else " <\_n>>
			<ブロック> 
		] 
		;

<while文>       "while"  		<x <errormsg "while文にエラー">>
			 		<printf "while (">
		<条件式> 		<printf ") " <\_n>>
		<ブロック> 
		;

<for文>       "for"
				 	<x <errormsg "for文にエラー">>
		<変数 #i>
		"in" "range" "("
		       (<NUM #n> | <変数 #n>)
		")"
			 		<printf "{"  <\_n>>
					<printf "int " #i ";" <\_n>> 
					<printf "for (" #i "=0; " #i " < ">
					<printf #n>
					<printf "; " #i "++) " <\_n>>
		<ブロック> 
					<printf "}" <\_n>>
		;

<print文>
	       "print"	  	 	<x <errormsg "print文にエラー">>
		<表示項目> 
			{","  		<printf 'printf(" ");' <\_n>>
			  <表示項目>}
					<printf 'printf("\n");' <\_n>>
		;

<表示項目>				<printf 'printf('>
		(
		   <STRINGS #s>		<printf '"%s","' #s '"'>
		 | 
					<printf '"%d", '>
		   <数式>
		)
					<printf ');' <\_n>>
		;

<代入文>
	        <変数 #v>
	 	 	 		<x <errormsg "代入文にエラー">>
		"="
					<printf #v>
					<printf " = ">
		<数式>			<printf ";" <\_n>>
		;

<数式>          <expradd>;

<expradd>       <exprmul> 
		{ "+" 			<printf "+">
			<exprmul> 
		| "-" 			<printf "-">
			<exprmul> 
		}
		;

<exprmul>       <exprID> 
		{ "*" 			<printf "*">
			<exprID> 
		| "/" 			<printf "/">
			<exprID> 
		}
		;

<exprID>        "+" <exprterm> 
		| "-" 			<printf "-">
			<exprterm> 
		| <exprterm>
		;

<exprterm>      "(" 			<printf "(">
			<数式> 
		")" 			<printf ")">
		| <NUM> 		<GETTOKEN #n>
					<printf #n>
		| <変数 #v>		<printf #v>
		;

<条件式> 		  	 	<x <errormsg "条件式にエラー">>
		<数式> 
		(">=" | ">" | "==" | "!=" | "<=" | "<") 
					<GETTOKEN #op>
					<printf #op>
		<数式>
		;

<変数 #x> 
		<SKIPSPACE>
		<RANGE #x a z>
		;

<コメント>	"#" <SKIPCR>
		;

<errormsg #x>
		::sys <line #n>
		<warn "error : " #n ":" #x>
		<exit>
		;
<errormsg #n #x>
		<warn "error : " #n ":" #x>
		<exit>
		;


?<compile>;

