@ECHO OFF
REM /////////////////
REM // L2J-SFJP 用 //
REM /////////////////

REM #############################################
REM # 環境変数 JAVA_HOME と ANT_HOME を設定してください。
REM # 下記は一例です。
rem SET JAVA_HOME=C:\Program Files\Java\jdk1.7.0
rem SET ANT_HOME=%ProgramFiles%\ant
rem SET ANT_HOME=C:\eclipse\plugins\org.apache.ant_1.7.1.v20100518-1145
rem SET ANT_HOME=C:\eclipse\plugins\org.apache.ant_1.7.1.v20090120-1145
rem SET ANT_HOME=C:\eclipse\plugins\org.apache.ant_1.7.0.v200803061910
rem SET ANT_HOME=C:\eclipse\plugins\org.apache.ant_1.7.0.v200706080842
REM #############################################

TITLE L2J-SFJP builder

IF NOT "%JAVA_HOME%" == "" GOTO :JAVA_HOME_FOUND
ECHO JAVA_HOME が設定されていません。jdk を探しています...
FOR /D %%I IN ("%ProgramFiles%\Java\jdk1.*" "%ProgramFiles(x86)%\Java\jdk1.*") DO SET JAVA_HOME=%%I
ECHO SET JAVA_HOME=%JAVA_HOME%
:JAVA_HOME_FOUND

IF NOT EXIST "%JAVA_HOME%\lib\tools.jar" CALL :DIE エラー:JAVA_HOME が正しくありません。
IF NOT EXIST "%ANT_HOME%\bin\ant.bat" CALL :DIE エラー:ANT_HOME が正しくありません。

javac -version 2>NUL||PATH %JAVA_HOME%\bin;%PATH%
javac -version 2>NUL||CALL :DIE エラー:javac.exeがみつかりません。

TITLE clean - L2J_DataPack_BETA
PUSHD ..\L2J_DataPack_BETA
CALL "%ANT_HOME%\bin\ant.bat" cleanAll
POPD
TITLE clean - L2J_Server_BETA
PUSHD ..\L2J_Server_BETA
CALL "%ANT_HOME%\bin\ant.bat" cleanAll
POPD
rem TITLE clean - L2_CommunityServer
rem PUSHD ..\L2_CommunityServer
rem CALL "%ANT_HOME%\bin\ant.bat" cleanAll
rem POPD

TITLE ビルド中...
CALL "%ANT_HOME%\bin\ant.bat"
IF NOT EXIST ..\L2J-server-dist\*.* CALL :DIE エラー:ビルドに失敗しました。

TITLE 圧縮ファイル作成中...
SET OUTPUT=%CD%\
PUSHD ..\L2J-server-dist
7z.exe a %OUTPUT%L2J-server-dist.7z .
rem 7z.exe a -tzip %OUTPUT%L2J-server-dist.zip .
POPD

TITLE ビルド 完了
ECHO ビルド 完了
msg * "ビルド 完了"
rem PAUSE
TITLE
GOTO :EOF

:DIE
@ECHO OFF
ECHO %1
TITLE %1
PAUSE
TITLE
EXIT 1
