# callmenu

ウインドウのメニューを実行する。(バージョン4.56以降)

    callmenu <menu ID>

## 解説

<menu ID> で指定されたメニューを実行する。ID については Keycode を参照。

## 例

    ; 表示中のスクリーンを選択
    callmenu 50280

    ; クリップボードへコピー
    callmenu 50210

    ; 現在のスクリーンをテキストファイルへ保存する。同梱の screencapture.ttl も参照。
    ; Configuration

    appendmode = 1        ; 0 or 1

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    getdate header #13#10"======== %Y-%m-%d %H:%M:%S ==========================================="#13#10#13#10

    if appendmode=0 then
    	getdate filename "screencapture_%Y%m%d-%H%M%S.txt"
    	fileopen fp filename 0
    else
    	fileopen fp 'screencapture.txt' 1
    endif

    if result <> 0 end

    ;select screen
    callmenu 50280

    mpause 500

    filewrite fp header

    offset = 0
    do
    	clipb2var buff offset
    	if result > 0 filewrite fp buff
    	offset = offset + 1
    loop while result = 2

    fileclose fp

    ;reset selection
    callmenu 50270

    end

    ; 漢字コードを選択する。TTX Kanji Menuのインストールが必要。
    ;callmenu 54010  ; [KanjiCode] Recv: Shift_JIS
    ;callmenu 54110  ; [KanjiCode] Send: Shift_JIS
    ;callmenu 54011  ; [KanjiCode] Recv: EUC-JP
    ;callmenu 54111  ; [KanjiCode] Send: EUC-JP
    ;callmenu 54012  ; [KanjiCode] Recv: JIS
    ;callmenu 54112  ; [KanjiCode] Send: JIS
    callmenu 54013  ; [KanjiCode] Recv: UTF-8
    callmenu 54113  ; [KanjiCode] Send: UTF-8
    ;callmenu 54014  ; [KanjiCode] Recv: UTF-8m