# send

Sends data.

    send <data1> <data2>....

## Remarks

Causes Tera Term to send characters to the host.
If <data> is a string, the string is sent to the host.
If <data> is an integer, its lowest-order byte (0-255) is regarded as an ASCII code of the character, and the character is sent to the host.

## Example

    send 'ABC'

    ; Send "ABC". (ASCII code of the character "A" is 65.)
    send  65 66 67

    myname='Tera Term'
    send 'My name is ' myname '.'

    ; "ABC"
    send $41 $42 $43

    ; "1"
    value = $31
    send value

    ; "31"
    value = $31
    sprintf2 command "%02X" value
    send command

    /* "CTRL+C" is 3 in binary so just send 3 like so.
     *
     * CTRL+A = 1, CTRL+B = 2.................. CTRL+Z = 26.
     */
    send #3

    /* Send the tab code. */
    send #9

See also "setsync" for the synchronous mode.

## See also

- sendln
- Formats of constants