# filereadln

ファイルから一行読む。

    filereadln <file handle> <strvar>

## 解説

ファイルハンドル <file handle> で指定されるファイルから一行読む。
読み込まれた行は、文字列変数 <strvar> に格納される。
ファイルポインタは次の行の始めへ移動する。もし、行を読んでいる間にファイルポインタがファイルの
最後に達した場合、システム変数 result に 1 が格納される。それ以外の場合、result に 0 が格納される。
改行のみの場合は、文字列変数は空となり、result には 0 が格納される。

## 例

    ; ファイルオープン
    fileopen fhandle 'test.txt' 0

    :loop
    ; 一行読み込み
    filereadln fhandle line
    if result goto fclose
    ; 読み込んだ行を表示
    messagebox line 'test.txt'
    ; ファイル最後まで繰り返す
    goto loop

    :fclose
    ; ファイルクローズ
    fileclose fhandle

    ; ファイルオープン
    fileopen fhandle 'test.txt' 0
    while 1
        ; 一行読み込み
        filereadln fhandle line
        if result=1 then
              break
        endif
        ; 読み込んだ行を表示
        messagebox line 'test.txt'
        ; ファイル最後まで繰り返す
    endwhile
    ; ファイルクローズ
    fileclose fhandle

    ; ファイルに含まれるキーワードを置換する
    infile = 'testdata.txt'
    outfile = 'testdata_output.txt'

    oldkeyword = 'BBB'
    newkeyword = 'zzz'

    fileopen ifd infile 0
    fileopen ofd outfile 0

    while 1
    	filereadln ifd line
    	if result=1 then
    		break
    	endif
    	strreplace line 1 oldkeyword newkeyword
    	filewriteln ofd line
    endwhile

    fileclose ifd
    fileclose ofd

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    [testdata.txt]
    AABBBCCCCDDDDD
    ###DDCCCBBBBAAAAA####
    1234567890

    [testdata_output.txt]
    AAzzzCCCCDDDDD
    ###DDCCCzzzBAAAAA####
    1234567890

## 参照

- strreplace
- fileopen
- filewriteln
- fileclose