////////////////////////////////////////////////////////////////////////////////////////////////////
// Includes
////////////////////////////////////////////////////////////////////////////////////////////////////

#include "../../../types.txt"

////////////////////////////////////////////////////////////////////////////////////////////////////
// Constant valus
////////////////////////////////////////////////////////////////////////////////////////////////////

static const float2 LD_TEX_CENTER = float2( 0.5, 0.5 );

////////////////////////////////////////////////////////////////////////////////////////////////////
// Structures
////////////////////////////////////////////////////////////////////////////////////////////////////

//͍\
struct PS_INPUT
{
#if MIX_SM_HIGH
	float4 pos : SV_POSITION;
#endif //MIX_SM_HIGH
	float2 tex : TEXCOORD0;
};

////////////////////////////////////////////////////////////////////////////////////////////////////
// Grobal values
////////////////////////////////////////////////////////////////////////////////////////////////////

#if MIX_SM_HIGH

	cbuffer cbInput : register( b0 )
	{
		float4 g_Param;
	};

	Texture2D    g_ColorTexture : register( t0 );
	SamplerState g_ColorSampler : register( s0 );

#else //MIX_SM_HIGH

	float4 g_Param : register( c0 );

	sampler g_ColorSampler : register( s0 );

#endif //MIX_SM_HIGH

////////////////////////////////////////////////////////////////////////////////////////////////////
// Macros
////////////////////////////////////////////////////////////////////////////////////////////////////

#if MIX_SM_HIGH
	#define TEX_COLOR( uv ) g_ColorTexture.Sample( g_ColorSampler, uv )
#else //MIX_SM_HIGH
	#define TEX_COLOR( uv ) tex2D( g_ColorSampler, uv )
#endif //MIX_SM_HIGH

#define LD_K g_Param.x

#if ENABLE_K_CUBE
	#define LD_K_CUBE g_Param.y
#endif //ENABLE_K_CUBE

#define LD_SCALE g_Param.z

////////////////////////////////////////////////////////////////////////////////////////////////////
// Main function
////////////////////////////////////////////////////////////////////////////////////////////////////

float4 main( PS_INPUT input ) : MSV_TARGET0
{
	float2 vec = input.tex - LD_TEX_CENTER;
	float r2 = dot( vec, vec );

	float f;
	float2 smpTex;

#if ENABLE_K_CUBE
	f = 1.0 + r2 * ( LD_K + LD_K_CUBE * sqrt( r2 ) );
#else //ENABLE_K_CUBE
	f = 1.0 + r2 * LD_K;
#endif //ENABLE_K_CUBE

	smpTex = vec * f * LD_SCALE + LD_TEX_CENTER;

	return TEX_COLOR( smpTex );
}
